feat(loader, kernel): impl part of loader and initialize kernel structure

2026-04-11 09:42:09 +08:00
parent 1233ae9e9b
commit 34ccf69569
53 changed files with 1743 additions and 777 deletions
--- a/arch/x86_64/boot/kcapsule.ld
+++ b/arch/x86_64/boot/kcapsule.ld
@@ -0,0 +1,59 @@
+OUTPUT_ARCH(i386:x86_64)
+
+ENTRY(startup_32)
+
+SECTIONS {
+    . = 0;
+    .head.text : {
+        KEEP(*(.head.text))
+    }
+    .rodata.compressed : {
+        *(.rodata.compressed)
+    }
+    .text : {
+        _text = .;
+        *(.text)
+        *(.text.*)
+        _etext = .; 
+    }
+    .rodata : {
+        _rodata = .;
+        *(.rodata)
+        *(.rodata.*)
+        _erodata = .;
+    }
+    .data : ALIGN(0x1000) {
+        _data = .;
+        *(.data)
+        *(.data.*)
+        . = ALIGN(. + 4, 0x200);
+        _edata = .;
+    }
+    .rela.dyn : {
+        __rela_dyn_start = .;
+        *(.rela.dyn)
+        __rela_dyn_end = .;
+    }
+    . = ALIGN(8);
+    .bss : {
+        _bss = .;
+        *(.bss)
+        *(.bss.*)
+        *(COMMON)
+        . = ALIGN(8);
+        _ebss = .;
+    }
+    . = ALIGN(4096);
+    .pgtable : {
+        _pgtable = .;
+        *(.pgtable)
+        _epgtable = .;
+    }
+    _end = .;
+    /DISCARD/ : {
+        *(.dynamic) *(.dynsym) *(.dynstr) *(.dynbss)
+        *(.hash) *(.gnu.hash)
+        *(.note.*)
+    }
+
+}